We use cookies on our website to ensure we provide you with the best experience on our website. By using our website, you agree to the use of cookies for analytics and personalized content.This website uses cookies. More Information
It seems like your browser didn't download the required fonts. Please revise your security settings and try again.
Barracuda SSL VPN

Attention

This Firmware Version Is Going End-Of-Support
As of 1st March 2019, all new sales for the Barracuda SSL VPN product will cease. Only renewals of software and hardware subscriptions for a maximum of one year are available for a limited time. 1st March 2020: All Barracuda SSL VPN sales will cease; neither new sales nor any renewals will be available. If you currently hold a maintenance and support contract, you will continue to receive our award-winning support and services until your contract expires.

How to Install the SSL VPN Agent in Non-interactive Mode

  • Last updated on

Running the Barracuda SSL VPN Standalone Agent installer in non-interactive mode allows distributed installation of the SSL VPN Agent on multiple clients. When the users launch the agent on their system they can login and then launch their SSL VPN resources directly from the taskbar. For information on how to manually install the SSL VPN Standalone Agent on a client, see SSL VPN Standalone Agent User Guide

Install the SSL VPN Agent using one of the following methods:

  • Automated – An automated installation of the SSL VPN Agent via MSAD group policy.
  • Silent – A silent installation that can be run manually or from a script.

Requirements

To install the SSL VPN Agent in non-interactive mode you need the following scripts:

agent.properties configuration file:

#Standalone Agent configuration

protocol=https

host=sslvpn.barracuda.com

port=443

locale=en

log4j=log4j.properties

 

#Proxy Server

clientProxy.type=http

clientProxy.hostname=192.168.0.1

clientProxy.port=3128

clientProxy.username=username

clientProxy.password=OBF\:1v2j1uum1xtv1zej1zer1xtn1uvk1v1v

clientProxy.ntlmDomain=domain

clientProxy.preferredAuthentication=BASIC

clientProxy.pacUrl=

 

extensionClasses=com.sslexplorer.enterprise.nac.agent.NacAgent,com.sslexplorer.agent.client.webforwards.WebForwardAgentExtension,com.
sslexplorer.agent.client.applications.ApplicationAgentExtension,com.sslexplorer.agent.client.tunneling.TunnelAgentExtension,com.
sslexplorer.agent.client.networkplaces.NetworkPlaceAgentExtension,com.sslexplorer.enterprise.deviceconfig.agent.
DeviceConfigurationAgentProxy,com.sslexplorer.drives.DrivesAgentProxy

allowUntrustedConnections=true

standaloneAgent.vbs file:

' Barracuda Networks SSL VPN Standalone Agent deployment script

' Copyright 2014 Barracuda Networks

'

' This script takes zero or more arguments:

' Optional arguments:

'               /responsefile:"\\server\share\responseFile.txt"                         Contains options to be pre-configured on the client

'               /dir:"C:\Program Files\Barracuda\SSL VPN Agent"                         Specifies non-default directory for installation

'               /uninstall                                                              Performs unattended uninstallation

 

' Set up basic environment

Set objFSO = CreateObject("Scripting.FilesystemObject")

Set objShell = CreateObject("WScript.Shell")

strSourceDir = objFSO.GetParentFolderName(WScript.ScriptFullName)

strArguments = "-q"

strDebug = false

 

' Read in any provided arguments

Set colNamedArguments = WScript.Arguments.Named

 

' Pick up the argument to point out where the properties file is

If colNamedArguments.exists("responsefile") Then strArguments = strArguments & " -varfile """ & colNamedArguments.Item("responsefile") & """"

 

' Check to see if the user wants to see a splash screen for debugging

If strDebug Then strArguments = strArguments & " -splash ""Barracuda Networks SSL VPN"""

 

' Check for a specified directory, otherwise use the default

If colNamedArguments.exists("dir") Then

                strTargetDir = colNamedArguments.Item("dir")

                strArguments = strArguments & " -dir """ & colNamedArguments.Item("dir") & """"

ElseIf Not colNamedArguments.exists("dir") Then

                strTargetDir = "C:\Program Files\Barracuda\SSL VPN Agent"

End If

 

If (colNamedArguments.exists("uninstall")) Then

                If objFSO.FileExists(strTargetDir & "\uninstall.exe") Then

                                If strDebug Then WScript.echo "DEBUG: Running " & strTargetDir & "\uninstall.exe" & " " & strArguments

                                objShell.Exec(strTargetDir & "\uninstall.exe" & " " & strArguments)

                End If

ElseIf Not (colNamedArguments.exists("uninstall")) Then

                If (is64Bit() = true) Then

                                strInstaller = strSourceDir & "\sslvpn-agent-windows-x86_64.exe"

                ElseIf (is64bit() = false) Then

                                strInstaller = strSourceDir & "\sslvpn-agent-windows-x86.exe"

                End If

                If (isInstallerNewer(strInstaller,strTargetDir & "\agent.exe") = true) Then

                                If strDebug Then WScript.echo "DEBUG: Running " & strInstaller & " " & strArguments

                                objShell.Exec(strInstaller & " " & strArguments)

                Else

                                If strDebug Then WScript.Echo "DEBUG: Installed agent is the same version or newer, doing nothing"

                End If

End If

 

Function is64Bit()

                Set objWMI = GetObject("winmgmts:\\.\root\CIMV2")

                set colProcessors = objWMI.ExecQuery("select AddressWidth from Win32_Processor where DeviceID=""CPU0""")

                For Each objProcessor in colProcessors

                                If (objProcessor.AddressWidth = 32) Then

                                                is64Bit = false

                                ElseIf (objProcessor.AddressWidth = 64) Then

                                                is64Bit = true

                                End If

                Next

End Function

 

Function isInstallerNewer(strInstaller,strAgent)

                strInstallerVersion = objFSO.GetFileVersion(strInstaller)

                If objFSO.FileExists(strAgent) Then

                                strAgentVersion = objFSO.GetFileVersion(strAgent)

                Else

                                strAgentVersion = "0"

                End If

                If strInstallerVersion > strAgentVersion Then

                                isInstallerNewer = true

                Else

                                isInstallerNewer = false

                End If

                If strDebug Then WScript.echo "DEBUG: Installer version is " & strInstallerVersion & " and agent version is " & strAgentVersion

End Function

Automated installation via group policy

Create a MSAD group policy object and link it to an OU. All clients in this OU will have the software automatically installed.

  1. Put the agent installers and the vbs file onto an accessible network share.
  2. Using the MSAD Group Policy Management Console, create a new group policy object linked to an OU.

In the group policy object adjust the startup script depending on your requirements.

  1. Edit the group policy object.
  2. Navigate to Computer Config > Policies > Windows Settings > Scripts > Startup.
  3. Change the startup script to one of the following, depending on your requirements.
Installation OptionsNameParameters
Install the SSL VPN Agent silently into the default location (C:\Program Files\Barracuda\SSL VPN Agent).\\server\share\standaloneAgent.vbs-
Silently uninstall the SSL VPN Agent from the default location (C:\Program Files\Barracuda\SSL VPN Agent)\\server\share\standaloneAgent.vbs/uninstall
Install the SSL VPN Agent silently into a specified location\\server\share\standaloneAgent.vbs/dir:"C:\SSL VPN Agent
Uninstall the SSL VPN Agent silently from the specified location\\server\share\standaloneAgent.vbs/dir:"C:\SSL VPN Agent" /uninstall

Install the SSL VPN Agent silently into the default location (C:\Program Files\Barracuda\SSL VPN Agent) and pre-configure to connect to sslvpn.barracuda.com (edit the agent.properties file to set the hostname).

\\server\share\standaloneAgent.vbs

/responsefile:"\\server\share\agent.properties

To install a pre-configured agent in a non-standard directory use /responsefile with /dir

When the installer is replaced with a later version, this should automatically cause the installer to be run once to upgrade the agent.

Silent installation

When performing a silent installation make sure you choose the right system version for your installation script.

To perform a silent installation either manually or via a script, run sslvpn-agent-windows-x86.exe -q -varfile \\server\share\agent.properties

-q (required) enables unattended mode.

-varfile (optional) tells the installer where to pick up preferences from (this file can be taken from a client which has had the agent manually installed)

Last updated on